程序代码

    <%

    'by xilou,www.chinacms.org,20090115

    '最后更新：20090115

    '修改记录：无

    CONST CACHEPREFIX = "CACHE_" '缓存前缀,不能为空

    '说明：

    '        1,缓存的格式为Application(CACHEPREFIX & key) = array("缓存key","缓存时间","缓存内容","缓存说明","到期时间")

    '          2,缓存key不区分大小写  

    '添加缓存,不检查缓存是否存在，如果存在则相当于更新缓存

    'varAry :  参数，格式为:array("缓存key","缓存时间","缓存内容","缓存说明")

    '           缓存key ：application()格式相同

    '           缓存时间：单位秒,可以为负数,表示立即过期,可以为空，空或不是数字则默认为20分钟过期

    '          缓存内容：缓存数据，不支持对对象的缓存

    '           缓存说明：缓存描述说明

    Function AddCache(varAry)

        Dim c,ary(4)

        If Not IsArray(varAry) Then

            Response.Write "Error:AddCache(varAry)参数错误，参数不是数组"

            Response.End()

        End If

        If UBound(varAry) <> 3 Then

            Response.Write "Error:AddCache(varAry)参数错误，数组长度错误"

            Response.End()

        End If

        If varAry(0) = "" Then

            Response.Write "Error:AddCache(varAry)错误，key不能为空"

            Response.End()

        End If

        If varAry(1) = "" or Not IsNumeric(varAry(1)) Then varAry(1) = 1200

        Application.Lock()

        Application(CACHEPREFIX & varAry(0)) = array(varAry(0),varAry(1),varAry(2),varAry(3),DateAdd("s",varAry(1),Now()))

        Application.UnLock()

    End Function

    '检查某个缓存是否存在,存在返回True否则返回False

    'key : 缓存key

    Function CheckCache(key)

        Dim k

        For Each k In Application.Contents

            If LCase(k) = LCase(CACHEPREFIX & key) Then CheckCache = True : Exit Function

        Next

        CheckCache = False

    End Function